diff --git a/src/strands/strands_api.js b/src/strands/strands_api.js
index 0bb0ce9866..8c85488eea 100644
--- a/src/strands/strands_api.js
+++ b/src/strands/strands_api.js
@@ -15,7 +15,7 @@ import { StrandsConditional } from './strands_conditionals'
 import * as CFG from './ir_cfg'
 import * as FES from './strands_FES'
 import { getNodeDataFromID } from './ir_dag'
-import noiseGLSL from '../webgl/shaders/functions/noiseGLSL.glsl';
+import noiseGLSL from '../webgl/shaders/functions/noise3DGLSL.glsl';
 
 //////////////////////////////////////////////
 // User nodes
@@ -125,15 +125,17 @@ export function initGlobalStrandsAPI(p5, fn, strandsContext) {
     strandsContext.fragmentDeclarations.add(noiseGLSL);
     // Handle noise(x, y) as noise(vec2)
     let nodeArgs;
-    if (args.length === 2) {
-      nodeArgs = [fn.vec2(args[0], args[1])];
+    if (args.length === 3) {
+      nodeArgs = [fn.vec3(args[0], args[1], args[2])];
+    } else if (args.length === 2) {
+      nodeArgs = [fn.vec3(args[0], args[1], 0)];
     } else {
       nodeArgs = args;
     }
 
     const { id, dimension } = build.functionCallNode(strandsContext, 'noise', nodeArgs, {
       overloads: [{
-        params: [DataType.float2],
+        params: [DataType.float3],
         returnType: DataType.float1,
       }]
     });
diff --git a/src/webgl/shaders/functions/noise3DGLSL.glsl b/src/webgl/shaders/functions/noise3DGLSL.glsl
new file mode 100644
index 0000000000..58dea1129f
--- /dev/null
+++ b/src/webgl/shaders/functions/noise3DGLSL.glsl
@@ -0,0 +1,108 @@
+// Based on https://github.com/stegu/webgl-noise/blob/22434e04d7753f7e949e8d724ab3da2864c17a0f/src/noise3D.glsl
+// MIT licensed, adapted for p5.strands
+
+vec3 mod289(vec3 x) {
+  return x - floor(x * (1.0 / 289.0)) * 289.0;
+}
+
+vec4 mod289(vec4 x) {
+  return x - floor(x * (1.0 / 289.0)) * 289.0;
+}
+
+vec4 permute(vec4 x) {
+  return mod289(((x*34.0)+10.0)*x);
+}
+
+vec4 taylorInvSqrt(vec4 r)
+{
+  return 1.79284291400159 - 0.85373472095314 * r;
+}
+
+float baseNoise(vec3 v)
+{
+  const vec2  C = vec2(1.0/6.0, 1.0/3.0) ;
+  const vec4  D = vec4(0.0, 0.5, 1.0, 2.0);
+
+  // First corner
+  vec3 i  = floor(v + dot(v, C.yyy) );
+  vec3 x0 =   v - i + dot(i, C.xxx) ;
+
+  // Other corners
+  vec3 g = step(x0.yzx, x0.xyz);
+  vec3 l = 1.0 - g;
+  vec3 i1 = min( g.xyz, l.zxy );
+  vec3 i2 = max( g.xyz, l.zxy );
+
+  //   x0 = x0 - 0.0 + 0.0 * C.xxx;
+  //   x1 = x0 - i1  + 1.0 * C.xxx;
+  //   x2 = x0 - i2  + 2.0 * C.xxx;
+  //   x3 = x0 - 1.0 + 3.0 * C.xxx;
+  vec3 x1 = x0 - i1 + C.xxx;
+  vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
+  vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y
+
+  // Permutations
+  i = mod289(i);
+  vec4 p = permute( permute( permute(
+          i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
+        + i.y + vec4(0.0, i1.y, i2.y, 1.0 ))
+      + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));
+
+  // Gradients: 7x7 points over a square, mapped onto an octahedron.
+  // The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
+  float n_ = 0.142857142857; // 1.0/7.0
+  vec3  ns = n_ * D.wyz - D.xzx;
+
+  vec4 j = p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)
+
+  vec4 x_ = floor(j * ns.z);
+  vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)
+
+  vec4 x = x_ *ns.x + ns.yyyy;
+  vec4 y = y_ *ns.x + ns.yyyy;
+  vec4 h = 1.0 - abs(x) - abs(y);
+
+  vec4 b0 = vec4( x.xy, y.xy );
+  vec4 b1 = vec4( x.zw, y.zw );
+
+  //vec4 s0 = vec4(lessThan(b0,0.0))*2.0 - 1.0;
+  //vec4 s1 = vec4(lessThan(b1,0.0))*2.0 - 1.0;
+  vec4 s0 = floor(b0)*2.0 + 1.0;
+  vec4 s1 = floor(b1)*2.0 + 1.0;
+  vec4 sh = -step(h, vec4(0.0));
+
+  vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
+  vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;
+
+  vec3 p0 = vec3(a0.xy,h.x);
+  vec3 p1 = vec3(a0.zw,h.y);
+  vec3 p2 = vec3(a1.xy,h.z);
+  vec3 p3 = vec3(a1.zw,h.w);
+
+  //Normalise gradients
+  vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
+  p0 *= norm.x;
+  p1 *= norm.y;
+  p2 *= norm.z;
+  p3 *= norm.w;
+
+  // Mix final noise value
+  vec4 m = max(0.5 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
+  m = m * m;
+  return 105.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1),
+        dot(p2,x2), dot(p3,x3) ) );
+}
+
+float noise(vec3 st) {
+  float result = 0.0;
+  float amplitude = 1.0;
+  float frequency = 1.0;
+
+  for (int i = 0; i < 4; i++) {
+    result += amplitude * baseNoise(st * frequency);
+    frequency *= 2.0;
+    amplitude *= 0.5;
+  }
+
+  return result;
+}
diff --git a/src/webgl/shaders/functions/noiseGLSL.glsl b/src/webgl/shaders/functions/noiseGLSL.glsl
deleted file mode 100644
index df5d8272a7..0000000000
--- a/src/webgl/shaders/functions/noiseGLSL.glsl
+++ /dev/null
@@ -1,40 +0,0 @@
-// Based on https://github.com/patriciogonzalezvivo/lygia/blob/main/generative/noise.glsl (MIT)
-// Adapted for use in p5.strands
-
-vec2 random2(vec2 st) {
-  st = vec2(dot(st, vec2(127.1, 311.7)),
-            dot(st, vec2(269.5, 183.3)));
-  return -1.0 + 2.0 * fract(sin(st) * 43758.5453123);
-}
-
-float baseNoise(vec2 st) {
-  vec2 i = floor(st);
-  vec2 f = fract(st);
-
-  vec2 a = random2(i);
-  vec2 b = random2(i + vec2(1.0, 0.0));
-  vec2 c = random2(i + vec2(0.0, 1.0));
-  vec2 d = random2(i + vec2(1.0, 1.0));
-
-  vec2 u = f * f * (3.0 - 2.0 * f);
-
-  return mix(mix(dot(a, f - vec2(0.0, 0.0)), 
-                 dot(b, f - vec2(1.0, 0.0)), u.x),
-             mix(dot(c, f - vec2(0.0, 1.0)), 
-                 dot(d, f - vec2(1.0, 1.0)), u.x), u.y);
-}
-
-// Fractal noise using 4 octaves
-float noise(vec2 st) {
-  float result = 0.0;
-  float amplitude = 1.0;
-  float frequency = 1.0;
-
-  for (int i = 0; i < 4; i++) {
-    result += amplitude * baseNoise(st * frequency);
-    frequency *= 2.0;
-    amplitude *= 0.5;
-  }
-
-  return result;
-}